WebGL not supported in this environment or syntax error

#version 300 es
// <3 to Xander, who sparked my love, passion,
// and awe for mathematics.
// Without him, I would not be where I am today!
// Much love Xander! <3

// Feel free to edit the shadercode here. It will update automatically on the canvas
// If you don't know what you're doing, I recommend just editing these #define tags
// If you are at all interested in holomorphic dynamics, please check out my webapp at https://dynamics.enslow.me !

#define COLORFUN 0.5 + 0.5 * cos(3.13938 + i * vec3(0.2, .25, 0.25) + vec3(0.219, 0.243, 0.735))
#define ITERATION 120.0

#define MANDELBROT 0 // change to 1 to display the mandelbrot set
#define ZOOMCURVE 5.0 * (1.0 - cos(u_time / 12.0))
#define ZOOMITERATION 25.0 + 25.0 * ZOOMCURVE

precision highp float;
out vec4 fragColor;

uniform vec2 u_resolution;
uniform vec2 u_offset;
uniform float u_time;

#define PI 3.141592
#define CENTER vec2(0.0, 0.0)

vec2 cmul(vec2 a, vec2 b) {
  return vec2(a.x * b.x - a.y * b.y, a.x * b.y + a.y * b.x);
}

// Parameterized along the Main Cardioid and Primary Bulb
vec2 path(in float t_raw) {
  float t = t_raw / 25.0;
  vec2 seed = vec2(0.0);

if (t < PI) {
    seed = vec2(0.5 * cos(t) * (1.0 - cos(t)) + 0.25, 0.55 * sin(t) * (1.0 - cos(t)));
  } else if (t < 3.0 * PI) {
    seed = vec2(-0.25 * cos(t) - 1.0, 0.25 * sin(t));
  } else {
    seed = vec2(0.5 * cos(t) * (1.0 - cos(t)) + 0.25, 0.55 * sin(t) * (1.0 - cos(t)));
  }

return seed;
}

// Ty iquilez! https://iquilezles.org/articles/msetsmooth/
float anon(in vec2 z) {
  const float B = 256.0;

float n = 0.0;

for (float i = 0.0; i < ITERATION; i += 1.0) {
    z = cmul(z, z) + path(u_time);
    if (dot(z, z) > (B * B)) {
      break;
    }
    n += 1.0;
  }
  if (length(z) < 1.5) {
    //For the julia sets with stable cycles with even periodicity
    return -1.0;
  }
  return n - log2(log2(dot(z, z)));
}

float mandelbrot(in vec2 c) {
  const float B = 256.0;
  float n = 0.0;
  vec2 z = vec2(0.0);

for (float i = 0.0; i < ZOOMITERATION; i += 1.0) {
    z = cmul(z, z) + c;
    if (dot(z, z) > (B * B)) {
      break;
    }
    n += 1.0;
  }
  if (length(z) < 2.0) {
    return -1.0;
  }
  return n - log2(log2(dot(z, z)));
}

void main() {
  vec2 pos = gl_FragCoord.xy;
  vec2 st;
  float i;
  if (MANDELBROT == 0) {
    st = (pos - vec2(0.5) * u_resolution) * 2.25 / u_resolution.y + CENTER;
    i = anon(st);
  } else {
    st = ((pos - vec2(0.5) * u_resolution) * 2.4 / exp(ZOOMCURVE) / u_resolution.y + vec2(-0.764, 0.101));
    i = mandelbrot(st);
  }
  vec3 col = COLORFUN;
  fragColor = vec4(col, 1.0);
}

enslow

Math lover, osu! player, and programmer from Portland, Oregon Oregon Outline With Heart

About

Hi, I'm enslow, and I'm currently working towards a masters degree at PSU in mathematics, so that I can teach community college. In my free time, I read books and visual novels, program, and play osu!.

If you want to contact me for any reason, feel free to shoot me a message on discord @enslow!